Skip to main content

Browse the archive

Staging
v0.5.1
https://github.com/python/cpython
09 December 2020, 11:06:31 UTC
Revision 4e30a845b4d2496dab25f0016cb597072c7355b1 authored by Christian Heimes on 30 November 2007, 22:12:06 UTC, committed by Christian Heimes on 30 November 2007, 22:12:06 UTC 
Merged revisions 59239-59244 via svnmerge from
 
svn+ssh://pythondev@svn.python.org/python/trunk

........
  r59240 | amaury.forgeotdarc | 2007-11-30 21:37:22 +0100 (Fri, 30 Nov 2007) | 2 lines

  Add a NEWS entry for r59231
........
  r59241 | amaury.forgeotdarc | 2007-11-30 21:51:40 +0100 (Fri, 30 Nov 2007) | 5 lines

  Issue #1521: on 64bit platforms, str.decode fails on very long strings.
  The t# and w# formats were not correctly handled.

  Will backport.
........
  r59242 | christian.heimes | 2007-11-30 22:11:28 +0100 (Fri, 30 Nov 2007) | 3 lines

  Fix for feature request #1528 Add os.fchmod
  Georg Brandl has added fchmod() and fchown(). I've contributed lchown but I'm not able to test it on Linux. However it should be available on Mac and some other flavors of Unix.
  I've made a quick test of fchmod() and fchown() on my system. They are working as expected.
........
1 parent 04a4eb3
Raw File
Tip revision: 4e30a845b4d2496dab25f0016cb597072c7355b1 authored by Christian Heimes on 30 November 2007, 22:12:06 UTC
Merged revisions 59239-59244 via svnmerge from
Tip revision: 4e30a84
build_pgo.bat 
@echo off
rem A batch program to build PGO (Profile guided optimization) by first
rem building instrumented binaries, then running the testsuite, and
rem finally building the optimized code.
rem Note, after the first instrumented run, one can just keep on
rem building the PGUpdate configuration while developing.

setlocal
set platf=Win32

rem use the performance testsuite.  This is quick and simple
set job1=..\tools\pybench\pybench.py -n 1 -C 1 --with-gc
set path1=..\tools\pybench

rem or the whole testsuite for more thorough testing
set job2=..\lib\test\regrtest.py
set path2=..\lib

set job=%job1%
set clrpath=%path1%

:CheckOpts
if "%1"=="-p" (set platf=%2) & shift & shift & goto CheckOpts
if "%1"=="-2" (set job=%job2%) & (set clrpath=%path2%) & shift & goto CheckOpts

set PGI=%platf%-pgi
set PGO=%platf%-pgo

@echo on
rem build the instrumented version
call build -p %platf% -c PGInstrument

rem remove .pyc files, .pgc files and execute the job
%PGI%\python.exe rmpyc.py %clrpath%
del %PGI%\*.pgc
%PGI%\python.exe %job%

rem finally build the optimized version
if exist %PGO% del /s /q %PGO%
call build -p %platf% -c PGUpdate
back to top